Que la geolocalización es muy útil está claro. ¿Quieres incluir un GPS en tus proyectos? Sigue leyendo y aprende como.

Conocer la localización de un objeto nos facilita muchas cosas y da lugar a muchos e interesantes proyectos. Hacer nuestro propio GPSTracker para registrar nuestros entrenamientos y salidas de montaña, un GPS para el coche, el dron o nuestra mascota, colocarlo a un globo sonda y poder recuperarlo…

Para ello utilizaremos el GPS6MV2, de bajo coste y fácil de encontrar por internet.

Esquema de conexiones

La comunicación se establece por serie por lo que únicamente necesitamos los pines VCC 3.3v, GND, RX y TX.

Como utilizaremos el monitor serie durante las pruebas, usamos la libreria SoftwareSerial.h y pasamos RX y TX a los pines 9 y 10.

Leyendo datos directamente desde el puerto Serie

Podemos verificar que el GPS funciona con el siguiente código:

// NEO6MV2
#include <SoftwareSerial.h>

const int pinRX = 9; // yellow
const int pinTX = 10; // Green

SoftwareSerial SerialGPS(pinTX, pinRX);
char c = ' ';

void setup()
{
 Serial.begin(9600);
 Serial.println("www.altaruru.com - GPS NEO6MV2 Arduino");
 SerialGPS.begin(9600);
}

void loop()
{
  if(SerialGPS.available())
  {
    c=SerialGPS.read();
    Serial.print(c);
    delay(10);
  }
}

Si abres el puerto Serie y verás una salida similar a esta:

www.altaruru.com - GPS NEO6MV2 Arduino
$GPRMC,,V,,,,,,,,,,N*53
$GPVTG,,,,,,,,,N*30
$GPGGA,,,,,,0,00,99.99,,,P,,90,4$GPRMC,,V,,,,,,,,,,N*53
$GPVTG,,,,,,,,,N*30
$GPGGA,,,,,,0,00,99.99,,,P,,90,4$GPRMC,,V,,,,,,,,,,N*53
$GPVTG,,,,,,,,,N*30
$GPGGA,,,,,,0,00,99.99,,,P,,90,4$GPRMC,,V,,,,,,,,,,N*53
$GPVTG,,,,,,,,,N*30
$GPGGA,,,,,,0,00,99.99,,,P,,901,G,$GPRMC,,V,,,,,,,,,,N*53
$GPVTG,,,,,,,,,N*30
$GPGGA,,,,,,0,00,99.99,,,P,,90,4$GPRMC,,V,,...

La salida es así por dos motivos, está sin decodificar y posiblemente estás en interior y el GPS no pilla coordenadas. Pero sabemos que funciona.

Libreria TinyGPS

Para hacernos la vida más fácil disponemos de la libreria TinyGPS, gracias a Arduiniana.

La descargamos y añadimos a Arduino desde el menú Programa/Incluir Libreria/Añadir Libreria Zip…


Código de ejemplo utilizando TinyGPS

// NEO6MV2
#include <TinyGPS.h> //incluimos TinyGPS
#include <SoftwareSerial.h>

const int pinRX = 9; // yellow
const int pinTX = 10; // Green

SoftwareSerial SerialGPS(pinRX, pinTX); // objeto serial GPS
TinyGPS tGPS;// objeto tinygps

unsigned long chars;
unsigned short sentences, failed_checksum;

void setup()
{
 Serial.begin(9600); 
 Serial.println("www.altaruru.com - GPS NEO6MV2 Arduino");
 Serial.println("v2. Utilizando tinyGPS");
 Serial.print("Testing TinyGPS library v. ");
Serial.println(TinyGPS::library_version());
 SerialGPS.begin(9600);
}

void loop()
{  
  while(SerialGPS.available())
  {
    int c = SerialGPS.read();
    if(tGPS.encode(c))
    {
      // process new gps info here
      float flat, flon;
      unsigned long fix_age;
      tGPS.f_get_position(&flat, &flon);
      float falt = tGPS.f_altitude(); // +/- altitude in meters
      Serial.print("Coordenadas (DD): "); 
      Serial.print(flat,5); 
      Serial.print(", "); 
      Serial.println(flon,5);
    }
  }
}

El ejemplo anterior recuperará las coordenadas y las muestra por el monitor serie.

Junto con la librería se instalan tres scketch de ejemplo en Arduino bastante amplios donde puedes ver como acceder a todos los datos del GPS:

#include <SoftwareSerial.h>
#include <TinyGPS.h>

/* This sample code demonstrates the normal use of a TinyGPS object.
   It requires the use of SoftwareSerial, and assumes that you have a
   4800-baud serial GPS device hooked up on pins 4(rx) and 3(tx).
*/

TinyGPS gps;
SoftwareSerial ss(10, 9);

static void smartdelay(unsigned long ms);
static void print_float(float val, float invalid, int len, int prec);
static void print_int(unsigned long val, unsigned long invalid, int len);
static void print_date(TinyGPS &gps);
static void print_str(const char *str, int len);

void setup()
{
  Serial.begin(115200);
  
  Serial.print("Testing TinyGPS library v. "); Serial.println(TinyGPS::library_version());
  Serial.println("by Mikal Hart");
  Serial.println();
  Serial.println("Sats HDOP Latitude  Longitude  Fix  Date       Time     Date Alt    Course Speed Card  Distance Course Card  Chars Sentences Checksum");
  Serial.println("          (deg)     (deg)      Age                      Age  (m)    --- from GPS ----  ---- to London  ----  RX    RX        Fail");
  Serial.println("-------------------------------------------------------------------------------------------------------------------------------------");

  ss.begin(4800);
}

void loop()
{
  float flat, flon;
  unsigned long age, date, time, chars = 0;
  unsigned short sentences = 0, failed = 0;
  static const double LONDON_LAT = 51.508131, LONDON_LON = -0.128002;
  
  print_int(gps.satellites(), TinyGPS::GPS_INVALID_SATELLITES, 5);
  print_int(gps.hdop(), TinyGPS::GPS_INVALID_HDOP, 5);
  gps.f_get_position(&flat, &flon, &age);
  print_float(flat, TinyGPS::GPS_INVALID_F_ANGLE, 10, 6);
  print_float(flon, TinyGPS::GPS_INVALID_F_ANGLE, 11, 6);
  print_int(age, TinyGPS::GPS_INVALID_AGE, 5);
  print_date(gps);
  print_float(gps.f_altitude(), TinyGPS::GPS_INVALID_F_ALTITUDE, 7, 2);
  print_float(gps.f_course(), TinyGPS::GPS_INVALID_F_ANGLE, 7, 2);
  print_float(gps.f_speed_kmph(), TinyGPS::GPS_INVALID_F_SPEED, 6, 2);
  print_str(gps.f_course() == TinyGPS::GPS_INVALID_F_ANGLE ? "*** " : TinyGPS::cardinal(gps.f_course()), 6);
  print_int(flat == TinyGPS::GPS_INVALID_F_ANGLE ? 0xFFFFFFFF : (unsigned long)TinyGPS::distance_between(flat, flon, LONDON_LAT, LONDON_LON) / 1000, 0xFFFFFFFF, 9);
  print_float(flat == TinyGPS::GPS_INVALID_F_ANGLE ? TinyGPS::GPS_INVALID_F_ANGLE : TinyGPS::course_to(flat, flon, LONDON_LAT, LONDON_LON), TinyGPS::GPS_INVALID_F_ANGLE, 7, 2);
  print_str(flat == TinyGPS::GPS_INVALID_F_ANGLE ? "*** " : TinyGPS::cardinal(TinyGPS::course_to(flat, flon, LONDON_LAT, LONDON_LON)), 6);

  gps.stats(&chars, &sentences, &failed);
  print_int(chars, 0xFFFFFFFF, 6);
  print_int(sentences, 0xFFFFFFFF, 10);
  print_int(failed, 0xFFFFFFFF, 9);
  Serial.println();
  
  smartdelay(1000);
}

static void smartdelay(unsigned long ms)
{
  unsigned long start = millis();
  do 
  {
    while (ss.available())
      gps.encode(ss.read());
  } while (millis() - start < ms);
}

static void print_float(float val, float invalid, int len, int prec)
{
  if (val == invalid)
  {
    while (len-- > 1)
      Serial.print('*');
    Serial.print(' ');
  }
  else
  {
    Serial.print(val, prec);
    int vi = abs((int)val);
    int flen = prec + (val < 0.0 ? 2 : 1); // . and -
    flen += vi >= 1000 ? 4 : vi >= 100 ? 3 : vi >= 10 ? 2 : 1;
    for (int i=flen; i<len; ++i)
      Serial.print(' ');
  }
  smartdelay(0);
}

static void print_int(unsigned long val, unsigned long invalid, int len)
{
  char sz[32];
  if (val == invalid)
    strcpy(sz, "*******");
  else
    sprintf(sz, "%ld", val);
  sz[len] = 0;
  for (int i=strlen(sz); i<len; ++i)
    sz[i] = ' ';
  if (len > 0) 
    sz[len-1] = ' ';
  Serial.print(sz);
  smartdelay(0);
}

static void print_date(TinyGPS &gps)
{
  int year;
  byte month, day, hour, minute, second, hundredths;
  unsigned long age;
  gps.crack_datetime(&year, &month, &day, &hour, &minute, &second, &hundredths, &age);
  if (age == TinyGPS::GPS_INVALID_AGE)
    Serial.print("********** ******** ");
  else
  {
    char sz[32];
    sprintf(sz, "%02d/%02d/%02d %02d:%02d:%02d ",
        month, day, year, hour, minute, second);
    Serial.print(sz);
  }
  print_int(age, TinyGPS::GPS_INVALID_AGE, 5);
  smartdelay(0);
}

static void print_str(const char *str, int len)
{
  int slen = strlen(str);
  for (int i=0; i<len; ++i)
    Serial.print(i<slen ? str[i] : ' ');
  smartdelay(0);
}

Un saludo!!

Deja tu comentario